dnl Process this file with autoconf to produce a configure script.
AC_INIT(src/act.comm.c)
AC_SUBST(MYFLAGS)
AC_SUBST(LIBOBJS)
AC_CONFIG_HEADER(src/conf.h)

dnl Checks for programs.
AC_PROG_CC

dnl If we're using gcc, use gcc options.
dnl If not, test for various common switches to make a 'cc' compiler
dnl compile ANSI C code.

if test $ac_cv_prog_gcc = yes; then
  MYFLAGS="-Wall -fno-strict-prototypes"
else
  MYFLAGS=""

  dnl -cckr for IRIX machines
  AC_CACHE_CHECK(whether ${CC-cc} accepts -cckr, ac_cv_prog_cc_cckr,
  [echo 'void f(){}' > conftest.c
  if test -z "`${CC-cc} -cckr -c conftest.c 2>&1`"; then
    MYFLAGS="-cckr"
    ac_cv_prog_cc_cckr=yes
  else
    ac_cv_prog_cc_cckr=no
  fi
  rm -f conftest*
  ])

fi

AC_CHECK_PROGS(MORE, more cat)

dnl Checks for libraries.
AC_CHECK_LIB(nsl, gethostbyaddr)
AC_CHECK_LIB(socket, socket)
AC_CHECK_LIB(malloc, malloc)
AC_CHECK_LIB(crypt, crypt)

dnl Checks for header files.
AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS(fcntl.h sys/fcntl.h errno.h net/errno.h string.h)
AC_CHECK_HEADERS(limits.h sys/time.h sys/select.h sys/types.h unistd.h)
AC_CHECK_HEADERS(memory.h crypt.h assert.h arpa/telnet.h)

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_HEADER_TIME

dnl Checks for library functions.
AC_TYPE_SIGNAL
AC_CHECK_FUNCS(crypt)
AC_CHECK_FUNCS(random, ,LIBOBJS="$LIBOBJS random.o")

AC_OUTPUT(src/Makefile)