#4300
Door Open Zap~
2 c 100
o~
if !(%arg% /= door || %arg% /= purple || %arg% /= glowing)
  return 0
  halt
end
if %cmd.mudcommand% != open
  return 0
  halt
end
if %actor.is_thief%
  %send% %actor% You are zapped by the doorknob and instantly let go of it.
  %echoaround% %actor% %actor.name% is zapped by the doorknob and instantly lets go of it.
  wait 3 s
  %echo% You hear faint, mocking laughter...
  return 1
else
  return 0
end
~
#4301
Floor Stomp~
2 c 100
stom~
%send% %actor% You stomp on the floor and crash through.
%echoaround% %actor% %actor.name% stomps on the floor and falls through into a pit.
%door% 4313 down room 4376
%door% 4313 down description There is a large hole in the floor. It doesn't look very safe.
%force% %actor% down
eval HasStomped 1
global HasStomped
return 1
~
#4302
Floor Reset~
2 f 100
~
if %HasStomped%
%echo% The hole in the floor is magically repaired.
%door% 4313 down purge
eval HasStomped 0
global HasStomped
end
~
#4303
Random Teleport Portal~
1 c 7
en~
if %arg% == portal || %arg% == blue
  %send% %actor% You step into the portal.
  %echoaround% %actor% %actor.name% steps into the portal.
  eval TheRoom %actor.room%
  eval Person %TheRoom.people%
  dg_cast 'teleport' %actor%
  while %Person%
    * %echo% DEBUG: person: %Person% %Person.name%
    if %Person.following% == %actor%
      * %echo% DEBUG: person is following
      %send% %Person% You follow %actor.name% into the portal.
      %echoaround% %Person% %Person.name% steps into the portal.
      %teleport% %Person% %actor.room%
      %force% %Person% look
    end
    eval Person %Person.next_in_room%
  done
  return 1
else
  return 0
end
~
#4304
Tunnel - Dig Rocks~
0 ab 50
~
if %self.fighting%
halt
end
%echo% The digger digs some rock out of the end of the tunnel.
%load% obj 4306
drop rubble
~
#4305
Tunnel - Haul Debris~
0 e 0
drops some rubble~
wait %random.40% s
eval ReturnSeg walk_to 4395 fly d d stand walk_to 4388 ocl e ccl poscheck rest
eval Path stand gar ocl w ccl walk_to 4305 fly u u stand walk_to 14206 gate_n walk_to 3030 drall walk_to 3127 gate_s %ReturnSeg%
while %Path.strlen% > 0
  if !%self.fighting%
    eval Action %Path.car%
    eval Path %Path.cdr%
    switch %Action%
      case walk_to
        eval Dest %Path.car%
        eval Path %Path.cdr%
        if %self.room% != %Dest%
          pathto Step %Dest%
          eval myroom %self.room%
          %Step%
          if %myroom% == %self.room%
            say Hmm...I seem to be lost.
            %echoc% %self.name% closes his eyes and utters the words, 'inset candusqirr'.
            %echoc% %self.name% disappears.
            %teleport% %self% 4373
            eval Path rest
          else
            eval Path walk_to %Dest% %Path%
          end
        end
        break
      case ocl
        open cloth
        break
      case ccl
        close cloth
        break
      case drall
        drop all.rubble
        wait 5
        get all 1.bag
        wait 5
        drop all.rubble
        wait 5
        get all 2.bag
        wait 5
        drop all.rubble
        break
     case gar
        get all.rubble
        wait 5
        put all.rubble 1.bag
        wait 5
        get all.rubble
        wait 5
        put all.rubble 2.bag
        wait 5
        get all.rubble
        break
      case gate_n
        n
        if %self.room% != 3127
          say Argh...the gate's locked.
          eval Path %ReturnSeg%
        end
        break
      case gate_s
        s
        while %self.room% != 14206
          if %self.room% != 3127
            say Hmm...I seem to be lost.
            %echoc% %self.name% closes his eyes and utters the words, 'inset candusqirr'.
            %echoc% %self.name% disappears.
            %teleport% %self% 4373
            eval Path rest
          end
          say Argh...the gate's locked.
          wait 5
          sit
          wait 75 s
          stand
          wait 5
          s
        done
        break
      case poscheck
        if %self.room% != 4373
          say Hmm...I seem to be lost.
          %echoc% %self.name% closes his eyes and utters the words, 'inset candusqirr'.
          %echoc% %self.name% disappears.
          %teleport% %self% 4373
          eval Path rest
        end
        break
      default
        %Action%
        break
    done
  end
  wait 1 s
  wait %random.5%
done
~
#4306
Ladder - Add Exit~
1 h 100
~
eval LadderCount 0%LadderCount% + 1
global LadderCount
%door% 4376 up room 4313
%door% 4376 up description A ladder leans agains the edge of the hole in the ceiling.
~
#4307
Ladder - Remove Exit~
1 g 100
~
eval LadderCount 0%LadderCount% - 1
global LadderCount
if %LadderCount% < 1
* doesn't work
* %door% 4376 up room -1
* %door% 4376 up description There is a jagged hole in the floorboards above you.
%door% 4376 up purge
end
~
#4308
Tunnel - Put up beam~
0 b 20
~
wait %random.3% s
if %self.inv_count(4310)% < 1
if %self.ground_count(4310)% < 1
say I seem to have run out of beams.
halt
end
get beam
end
%echo% The bracer puts up a beam.
mjunk beam
~
#4309
Fall Down Shaft~
2 c 100
d~
if !(%cmd.mudcommand% == down) || %actor.position% == 9
  return 0
  halt
end
%send% %actor% You jump into the hole.
%echoaround% %actor% %actor.name% jumps into the hole.
%teleport% %actor% 4390
%force% %actor% l
%echoaround% %actor% %actor.name% has fallen in from above.
* wait 5
%send% %actor% You fall down the shaft.
%echoaround% %actor% %actor.name% falls down the shaft.
%teleport% %actor% 4305
%force% %actor% l
%echoaround% %actor% %actor.name% has fallen in from above.
~
#4310
Generic use-staff-when-dying~
0 l 25
~
use staff
while %self.fighting%
  wait 15 s
done
~
#4311
Bird Flying~
0 ab 50
~
eval Directions n e s w
extract Direction %random.4% %Directions%
wait %random.10% s
%Direction%
if %random.4% == 2
  wait %random.10% s
  %Direction%
end
~
#4312
Joe Collects Objects~
0 n 100
~
get all
~
$~