#3500
Innkeeper Speech~
0 d 2
-unused-~
if %actor.vnum% != -1
  halt
end
wait 3
if %speech% /= reward
  'Oh yes, no less than 10000 coins. I put up half myself.
  'Anything to help a friend.
elseif %speech% /= niece || %speech% /= prize
  %echo% %self.name% points to the southwest.
  'They have captured the bard's niece, and no one has been
  'able to find her. We offered a reward, but alas, no one
  'has claimed.
elseif %speech% /= bard || %speech% /= man
  %echoc% %self.name% points to the southwest.
  'Thats the poor man, he's been looking for his niece for
  'weeks now.
  wait 1
  'I know they have her, but no one we know can
  'track those good for nothing bandits. So, we offered a
  'reward, but alas, no one has claimed.
elseif %speech% /= boy || %speech% /= child
  'Oh no, they tried to take Billy!!  Damn them, haven't
  'they got enough of our children? They are nothing but
  'a bunch of slavers. I'd thought they'd left for good.
elseif %speech% /= trouble || %speech% /= slaver || %speech% /= bandit
  frown
  'Well to be quite honest, we've been having a bit of
  'trouble with some slavers lately. They've been taking
  'the children. The poor bard's niece was their latest
  'prize.
elseif %speech% /= job || %speech% /= work
  'Why, I am the Innkeeper, of course.
  wait 10
  chuckle
elseif %speech% /= name || %speech% /= who
  'I am Andros, the innkeeper.
en
~
#3501
Innkeeper Greet~
0 g 100
~
if %actor.vnum% != -1
  halt
end
wait %random.12% s
%echoc% %self.name% looks southwest.
wait 1 s
'The poor bard; he's been drinking all day.
~
#3502
Bard Random~
0 b 60
~
wait %random.10% s
sniff
~
#3503
Bard Receive~
0 j 100
~
if %actor.vnum% != -1
  halt
end
return 1
wait 1 s
if %object.vnum% == 3509
  if %talkingto% != 0
    makeuid talkactor %talkingto%
    if %talkactor.room% == %self.room% && %talkingto% != %actor.id%
      'Sorry, but I'm still working on %talkactor.name%'s.
      give ale %actor.name%
      halt
    end
  end
  'Thank you.
  wait 1 s
  * drink ale
  %echoc% %self.name% drinks from the bottle.
  mjunk bottle
  eval talkingto %actor.id%
  global talkingto
  eval HasAskedBegin 0
  global HasAskedBegin
elseif %object.vnum% == 3600
  cry
  wait 3 s
  sniff
  wait 3 s
  if %actor.quest(3)% == 1
    'Thank you for finding her.
    give 10000 coins %actor%
    mquest %actor% 3 2
    wait 2 s
    'I shall write a song for my niece.
    'Meet me at the graveyard in Midgaard for the funeral if you would like to hear it.
    wait 5
    stand
    %echoc% %self.name% leaves to the east.
    %teleport% %self% 3402
    %load% obj 3511
    put corpse coffin
    close coffin
  else
    sigh
    wait 1 s
    %echoc% %self.name% gets up and leaves to the east.
    %teleport% %self% 1
    mjunk corpse
    %purge% %self%
  end
else
  'I don't need this.
  give all %actor.name%
end
~
#3504
Bard Speech~
0 d 4
*~
if %actor.vnum% != -1
  halt
end
wait 3
if %actor.quest(3)% != -1 && (%talkingto% == 0 || %actor.quest(3)% == 127)
  'Please leave me alone.
  halt
end
if %talkingto% && %talkingto% != %actor.id%
  makeuid talkactor %talkingto%
  if %talkactor.room% == %self.room%
    'Go away; I'm talking to %talkactor.name% right now.
  else
    'Please leave me alone.
  end
  halt
end
if %speech% /= find || %speech% /= search || %speech% /= help || %speech% /= reward || %speech% /= payment
  'I am offering a good reward for anyone that can bring her to me.
  'She was wearing a plain blue dress when I saw her last.
  wait 1
  if %actor.quest(3)% == 0 && !%actor.is_warrior%
    'Would you look for her?
    eval HasAskedBegin 1
    global HasAskedBegin
  end
elseif %speech% /= yes || %speech% /= sure || %speech% /= okay
  if %actor.quest(3)% == -1
    %load% obj 3510
    give song %actor.name%
  elseif %HasAskedBegin% == 1
    mquest %actor% 3 1
    'Thank you. I hope you can find her.
    eval HasAskedBegin 0
    global HasAskedBegin
  elseif %HasAskedFound% == 1 && %actor.quest(3)% == 1
    'Well, could you bring her to me?
  end
elseif %speech% /= no
  if %actor.quest(3)% == -1
    'Okay.
  elseif %HasAskedBegin% == 1 && %actor.quest(3)% == 0
    mquest %actor% 3 127
    'If you will not help me, then please leave.
    eval talkingto 0
    global talkingto
    eval HasAskedBegin 0
    global HasAskedBegin
  elseif %HasAskedFound% == 1 && %actor.quest(3)% == 1
    'I hope you find her soon.
  end
elseif %speech% /= house || %speech% /= hideout
  'There is a run down house to the west of here. I thought it was the
  'slaver hideout, but it seems I was wrong. Hope is lost, the slavers
  'could be many miles distant by now. I wish someone could help me find
  'her.
elseif %speech% /= slaver || %speech% /= take || %speech% /= bandit
  'Yes, they took her on a trail just south of here. I tracked
  'them to an abandoned house, but her abductors were nowhere to be
  'found.
elseif %speech% /= niece || %speech% /= missing
  'She was taken, nearly ten days ago, by the slavers.
  wait 2
  sniff
  wait 6
  'I have offered a reward for anyone who can find her,
  wait 1
  'but no one has claimed it.
elseif %speech% /= job || %speech% /= work
  'I used to be a traveling bard, but now I can only search for my
  'poor, missing niece.
end
~
#3505
Bard Greet~
0 g 100
~
if %actor.vnum% != -1
  halt
end
wait 3
if %actor.quest(3)% == -1
  'Hello, %actor.name%. Would you like a copy of my song?
  halt
end
if %actor.quest(3)% == 1
  'Hello, %actor.name%. Have you found my niece yet?
  eval HasAskedBegin 0
  eval HasAskedFound 1
  global HasAskedBegin
  global HasAskedFound
  halt
end
if %actor.quest(3)% != 2
  halt
end
if %self.room% != 3402
  halt
end
say Hello, %actor.name%.
wait 1 s
* need to change this
w
%force% %actor% w
wait 3 s
drop coffin
wait 5 s
emote nods at the priest.
* wait 5 s
* %echoc% %self.name% sings a song in tribute to his niece.
mquest %actor% 3 -1
* wait 3 s
* e
* %teleport% %self% 3607
* sit
~
#3506
Song Paper~
1 c 3
re~
if !(%arg% /= paper || %arg% /= song)
  return 0
  halt
end
if %cmd.mudcommand% == recite
  if %actor.quest(3)% != -1
    * %echo% DEBUG: quest incomplete
    return 0
    halt
  end
  if %actor.move% < 50
    %send% %actor% You are too exhausted.
    return 1
    halt
  end
  nop %actor.move(-50)%
  %send% %actor% You sing a song of death and loss.
  %echoaroundc% %actor% %actor.name% sings a song of death and loss.
  eval Leader %actor.following%
  if !%actor.following%
    eval Leader %actor%
  end
  eval TheRoom %actor.room%
  eval Person %TheRoom.people%
  eval HasFolInRoom 0
  while %Person%
    * %echo% DEBUG: person: %Person% %Person.name%
    if %Person.following% == %Leader% && %Person.is_grouped%
      dg_cast 'enrage' %Person.name%
      eval HasFolInRoom 1
    else
      * %echo% DEBUG: %Person.name% isn't in the group
    end
    eval Person %Person.next_in_room%
    * wait 1
  done
  if %HasFolInRoom%
    eval Person %Leader%
    dg_cast 'enrage' %Person.name%
  else
    %send% %Leader% Unfortunately, there's nobody to hear it.
  end
  return 1
else
  return 0
  halt
end
~
#3507
Graveyard Section Entry~
2 g 100
~
if %actor.quest(3)% != 2
  halt
end
%load% mob 3506
%force% bard stand
%load% mob 3405
%force% priest stand
~
$~