#3300
Cowgirl Quest - Greetings~
0 g 100
~
*Cowgirl Quest Suggestion
if (%actor.vnum% != -1)
    halt
end
*reset globals on char
eval GaveSpeech 0
Global GaveSpeech
eval WaitReply 0
Global WaitReply
*Actor has declined the quest.
if (%actor.quest(2)%  == 127)
    frown
    sniff
  wait 1s
    say If you will not help me, then leave me alone.
    slap %actor%
    msend %actor% The cowgirl throws you out.
    mforce %actor% west
    halt
end
* Actor is not on the quest as of yet.
if (%actor.quest(2)%  == 0)
    sniff
  wait 1s
    say My beloved trophy!
  wait 1s
    cry
    msend %actor% She looks quite sad, perhaps you should comfort her. 
    halt
end
* Actor allready returned the trophy or completed the quest?
if (%actor.quest(2)%  >= 3) || (%actor.quest(2)%  == -1)
    say Oh thank you again for all you have done, %actor.name%
    say You have all my gratitude!
    halt
end
* Actor is on the quest
say Oh you have returned, %actor.name%!
wait 1s
say Have you wresteled my prized trophy from those bandits?
eval  WaitReply 1
Global WaitReply
~
#3301
Cowgirl Quest Speech~
0 c 100
c~
*Cowgirl Quest Speech
if %actor.vnum% != -1
    halt
end
if %actor.quest(2)%  == 127
    halt
end
if %cmd.mudcommand% != comfort
    halt
end
%echoaround% %actor% %actor.name% comforts the poor cowgirl.
%send% %actor% You comfort the poor cowgirl.
*Give char the story.
if (%actor.quest(2)%  == 0)
  wait 1s
    say Oh thank you so much for your kindness, %actor.name%
  wait 2s
    * Allready Gave the Speech
    if  (%GaveSpeech% == 1)
        halt
    end
    say My life is a hard one as it is...
    say The only joy that came to it was last year.
  wait 3s
    say I had won 1st place in the fair's riding competition.
  wait 3s
    sniff
    say Now the memory of that has been taken from me.
  wait 3s
    say There is a band of horrid and evil bandits
    say They terrorize our village and steal livestock.
  wait 2s
    say The bastards have now stolen my prized trophy!
    sniff
  wait 4s
    say We caught one of the bandit's group stealing horses.
    say But...
  wait 3s
    say Even though we beat him senseless....
  wait 3s
    say He would not reveal their camp's location.
  wait 4s
    say So we hung the fucker from a tree.
    smile
  wait 4s
    say I would be very happy if only you would retrieve my award.
  wait 3s
    say I do not have much cash, but I do know things.
  wait 2s
    say I could teach you the art of horseback riding.
  wait 2s
    say Sadly that's all I can offer.
  wait 3s
    say Will you please help me?
    eval GaveSpeech 1
    Global GaveSpeech
    eval WaitReply 1
    Global WaitReply
end
~
#3302
Cowgirl Quest (acceptance)~
0 d 100
yes~
* Cowgirl Quest Acceptance
if (%WaitReply% == 0)
    halt
end
if (%actor.vnum% != -1)
    halt
end
* Actor is joining quest
if (%actor.quest(2)%  == 0)
  wait 1s
    hug %actor%
    say Oh thank you.  Please find my trophy.
    say I miss it so much.
  wait 2s
    kiss %actor%
    say I have faith in you, %actor.name%
    say You will not fail.
    mquest %actor% 2 1
    eval WaitReply 0
    Global WaitReply
    halt
end
* Actor is allready on quest
if (%actor.quest(2)%  != -1)
    say You have found it?
    say Oh please give me my trophy!
    smile %actor%
    halt
end
~
#3303
Cowgirl Quest (decline)~
0 d 100
no~
* Cowgirl Quest Decline
if (%WaitReply% == 0)
    halt
end
if (%actor.vnum% != -1)
    halt
end
* Actor just declined the quest
if (%actor.quest(2)% == 0)
  wait 1s
    frown
    say I will find someone to help me.
    say Now leave me to my sorrow.
    mquest %actor% 2 127
    mforce %actor% west
    halt
end
* Actor is allready on quest
if (%actor.quest(2)%  != -1)
  wait 1s
    frown
  wait 1s
    say Oh please don't give up.
  wait 2s
    cry
    halt
end
~
#3304
Cowgirl Quest (Duwick's Taunt)~
0 g 100
~
*Duwick taunts actor on quest
if (%actor.vnum% != -1)
    halt
end 
if (%actor.quest(2)% == 1)
  wait 1s
    say My spies have told me I should expect you.
    say I shall polish my knife with your blood, %actor.name%!
    grin
end
~
#3305
Cowgirl Quest (Duwick's Death)~
0 f 100
~
* Duwick's Death Script
if (%actor.vnum% != -1)
    halt
end
if (%actor.quest(2)% == 1)
    mquest %actor% 2 2
    mload obj 3322
end
~
#3306
Cowgirl Quest (Recieve Trophy)~
0 j 100
~
* Cowgirl receives a Trophy
if (%actor.vnum% != -1)
    halt
end
if (%object.vnum% != 3322)
    halt
end
*Actor isn't on the quest
if (%actor.quest(2)% == 0)
  wait 1s
    sniff
  wait 1s
    say I've been looking for a trophy like this...
  wait 1s
    say I know who can find it's owner, thanks, %actor.name%.
    sniff
    mjunk %object.name%
    halt
end
*Actor IS on the quest
if (%actor.quest(2)% == 1)
  wait 1s
    say This is a forgery!  Where did you get this, %actor.name%?
  wait 2s
    sniff
    mecho The cowgirl throws the trophy in the trash.
    mjunk %object.name%
  wait 2s
    say Now please go find me the real one.  The bandits stole it!
    halt
  wait 2s
    cry
end
*Actor allready gave cowgirl this trophy
if ( (%actor.quest(2)% == -1) | (%actor.quest(2)% >= 3) )
  wait 1s
    mecho The cowgirl examines the trophy.
  wait 1s
    say You allready gave me my trophy.
    say What are you trying to pull, %actor%?
    slap %actor%
    say Get out of here you con artist!
    mforce %actor% west
    mjunk %object.name%
    halt
end
*Ok sanity checks over.  Now for the meat.
if (%actor.quest(2)% == 2)
  wait 1s
    say My Trophy!!!!
    hug %actor%
    kiss %actor%
  wait 2s
    say And all I have to reward you with is my talent...
  wait 3s
    say I'll teach you the arts of horseback riding.
  wait 4s
    %send% %actor% The cowgirl shows you how to mount a horse and ride it.
    msetskill %actor.name% 'riding' 100
    mquest %actor% 2 -1
    %junk% %object.name%
    nop %actor.qpoints(1)%
  wait 3s
    say Go now, have fun, and thank you ever so dearly!
    mecho The cowgirl rubs her trophy with delight.
    halt
end
~
#3307
Cowgirl Quest Letter~
0 j 100
~
* No npc's thank you much
 if (%actor.vnum% != -1)
    halt
   end
* Object is no the letter
if (%object.vnum% != 3327)
 halt
end
* Haven't obtained the letter legally - exit
if (%actor.quest(2)% != 3)
wait 1
mecho Hugo examines the letter.
wait 5s
frown
wait 1s
mecho Hugo throws the letter into the air, shredding it with his sword!
wait 3s
accuse %actor.name%
wait 3s
say You can't trick me that easily.
say Now get the hell out of here before you end up looking like that letter.
mjunk %object.name%
halt
end
* Read the letter
wait 1
mecho Hugo examines the letter.
wait 5s
smile
wait 2s
say It's great to hear from Annie.
mquest %actor% 2 4
mjunk %object.name%
say Annie was my childhood sweetheart.
say She wrote me about the situation with the bandits last month.
wait 2s
say But my duties here prevented me from doing anything.
wait 3s
say Thank you for helping her in this matter.
say For your courage and effort, I'll give you some training.
wait 2s
mechoaround %actor.name% Looks over %actor.name% and raises and eyebrow.
msend %actor% Hugo stares at you, and raises an eyebrow.
wait 2s
ponder
wait 3s
say Aha!  I see you are only wielding one weapon.
wait 1s
say I will train you in using more than one.
* Not enough practices
if (%actor.practices% < 4)
wait 2s
say However, right now you don't have enough practices...
say Come talk to me again when you have more time to practice.
halt
end
* Ok teach away
wait 2s
mechoaround %actor.name% Hugo shows %actor.name% how to properly use two weapons.
msend %actor.name% Hugo explains to you how to properly hold two weapons.
wait 2s 
say I have not seen many people as ambidexterous as you, %actor.name%!
pat %actor.name%
wait 2s
smile
say Tell Annie I said hello.
mquest %actor% 2 -1
msetskill %actor.name% 'dual wield' 100
nop %actor.practices(-4)%
~
#3308
Cowgirl Quest Training~
0 g 100
~
* Actor Returns to practice at a later date
if (%actor.vnum% != -1)
halt
end
* Actor hasn't returned the letter
if (%actor.quest(2)% != 4)
halt
end
say Hello again, %actor.name%.  Have you returned for your training?
*Actor hasn't enough practices.
if (%actor.practices% < 4)
wait 2s
say What a shame, %actor.name%.  You still have not enough practices?
say Come talk to me again when you have more time to practice.
halt
end
* Ok teach away
wait 2s
mechoaround %actor.name% Hugo shows %actor.name% how to properly use two weapons.
msend %actor.name% Hugo explains to you how to properly hold two weapons.
wait 2s 
say I have not seen many people as ambidexterous as you, %actor.name%!
pat %actor.name%
wait 2s
smile
say Tell Annie I said hello.
mquest %actor% 2 -1
msetskill %actor.name% 'dual wield' 100
nop %actor.practices(-4)%
~
$~