#30100
Fish Decay~
1 f 100
~
if %self.vnum% > 30100 && %self.vnum% < 30104
    if !%self.carried_by%
        %echoc% %self.name% has decayed into a mere skeleton.
    else
        %sendc% %self.carried_by% %self.name% has decayed into a mere skeleton.
    end 
    otransform 30105
    halt
end
if %self.vnum% == 30105
    if !%self.carried_by%
        %echoc% %self.name% dissolves into nothingness.
    else
        %sendc% %self.carried_by% %self.name% dissolves into nothingness.
    end 
    opurge %self%
    halt
end
mudlog NOTE: mobile "%self.name%" (vnum %self.vnum) has script #30100 (fish decay)
echo AAAH!  A bug!  Tell an admin to check the logs!
~
#30101
Gon' Fishin!~
0 ab 100
~
wait 15s
wait %random.20%s
emote drops his line into the water as it makes a plop noise.
wait 25s
wait %random.14%s
if %random.4%-1
    emote reels in his line.
    wait 4s
    if %random.3%-1
        emote inspects the line.
        wait 2s
        emote grumbles.
        wait 3s
        emote baits the hook.
    else
        emote inspects the line.
        wait 2s
        shrug
        say Still there.
    end
else
    %echoc% %self.name%'s line begins to pull.
    wait 3s
    emote yanks the fishing pole.
    wait 2s
    emote reels in.
    wait 4s
    emote pulls back on the fishing pole.
    wait 2s
    emote reels in.
    wait 2s
    wait %random.4%s
    if %random.5%-1
        %echoc% %self.name%'s line goes loose.
        wait 3s
        curse
        emote begins to reel in the line.
    else
        eval fish_size %random.6%
        if %fish_size% < 4
            emote lifts a tiny fish out of the water.
            wait 3s
            emote looks a the tiny fish.
            wait 3s
            say damn
            wait 2s
            emote removes the fish from the hook.
            wait 3s
            %load% o 30101
            drop tiny
            wait 2s
            sigh
            wait 5s
            emote baits his hook.
        elseif %fish_size% <6
            emote lifts a good sized fish out of the water.
            wait 3s
            emote inspects the fish.
            wait 3s
            say looks like a keeper!
            wait 2s
            %load% o 30102
            put medium box
            wait 5s
            emote baits his hook.
        else
            emote lifts a huge fish out of the water!
            wait 3s
            say looks like a keeper!
            wait 2s
            %load% o 30103
            put huge box
            whistle
            wait 5s
            emote baits his hook.
        end
    end
end
~
#30102
Big Fish eat Little Fish~
0 g 50
~
* Note that this script should only be used on mobiles
*   who's sizes are in ascending order (with their vnums)
*   ie mobile 30103 will eat mobile 30102, but mobile 30103
*   will not eat mobile 30101.
if %actor.vnum% == %self.vnum%-1
    emote looks hungrily at %actor.name%.
    wait 3s
    emote eats %actor.name%.
    %purge% %actor%
end
~
#30103
Board Yacht~
1 c 4
board~
if %arg% == yacht
    %echoaroundc% %actor% %actor.name% boards the yacht.
    %teleport% %actor% 30275
    %force% %actor% stand
    %send% %actor% You board the yacht.
    %force% %actor% l
    %echoaroundc% %actor% %actor.name% boards the yacht.
end
~
#30104
new trigger~
1 f 100
~
say My trigger commandlist is not complete!
~
$~