parent $time_root
object $dark_time

var $root child_index 0
var $root owners [$dark_time]
var $root fertile 0
var $root inited 1
var $time_root created_on 695533749
var $time_root hours_per_day 21
var $time_root days_per_year 345
var $time_root year_begin 425
var $time_root secs_per_min 60
var $time_root secs_per_hour 4320
var $time_root secs_per_day 90720
var $time_root secs_per_week 453600
var $time_root secs_per_year 41731200
var $time_root mins_per_hour 72
var $time_root standard 0
var $root owned [$dark_time]
var $root manager $dark_time
var $root writable [$dark_time]
var $root readable ['parameters, 'methods, 'code]
var $root dbref 'dark_time

method paradise_time
    arg [args];
    var time, hour, mde;
    
    // args: terran time() == output of server builtin.
    //       'seconds      == with seconds
    //       'no_mde       == with morning/day/evening hour pre-pension
    if (args && (type(args[1]) == 'integer)) {
        time = .convert(args[1]);
        args = delete(args, 1);
    } else {
        time = .time();
    }
    hour = .hour(time);
    mde = (hour > 7) ? (hour > 14) ? "eh " | "dh " | "mh ";
    if (args && ('no_mde in args))
        mde = "";
    hour = hour % 7;
    hour = (hour == 0) ? 7 | hour;
    if (args && ('seconds in args))
        return ((((mde + tostr(hour)) + ":") + pad(tostr(.minute(time)), 2, "0")) + ":") + pad(tostr(.second(time)), 2, "0");
    else
        return ((mde + tostr(hour)) + ":") + pad(tostr(.minute(time)), 2, "0");
.

method ilraitheen_time
    arg [args];
    var time;
    
    // args: terran time() == output of server builtin.
    //       'seconds      == with seconds
    if (args && (type(args[1]) == 'integer)) {
        time = .convert(args[1]);
        args = delete(args, 1);
    } else {
        time = .time();
    }
    if (args && (type(args[1]) == 'symbol))
        return (((tostr(.hour(time)) + ":") + pad(tostr(.minute(time)), 2, "0")) + ":") + pad(tostr(.second(time)), 2, "0");
    else
        return (tostr(.hour(time)) + ":") + pad(tostr(.minute(time)), 2, "0");
.